أحدث البرامج التعليمية وتطوير الشبكة
 

حذف السجلات ADO

❮ السابق التالي الفصل ❯

قد نستخدم SQL حذف الأوامر لحذف سجل في جدول في قاعدة بيانات.

حذف السجلات في الجدول

نحن نريد أن حذف سجل في جدول العملاء في قاعدة بيانات Northwind. علينا أولا إنشاء جدول يسرد كافة السجلات في جدول العملاء:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs=Server.CreateObject("ADODB.Recordset")
rs.open "SELECT * FROM customers",conn
%>

<h2>List Database</h2>
<table border="1" width="100%">
<tr>
<%
for each x in rs.Fields
  response.write("<th>" & ucase(x.name) & "</th>")
next
%>
</tr>
<% do until rs.EOF %>
<tr>
<form method="post" action="demo_delete.asp">
<%
for each x in rs.Fields
  if x.name="customerID" then%>
    <td>
    <input type="submit" name="customerID" value="<%=x.value%>">
    </td>
  <%else%>
    <td><%Response.Write(x.value)%></td>
  <%end if
next
%>
</form>
<%rs.MoveNext%>
</tr>
<%
loop
conn.close
%>
</table>

</body>
</html>

إذا نقر المستخدم على زر في "customerID" عمود انه أو انها سوف يتم نقلك إلى ملف جديد يسمى "demo_delete.asp" . و "demo_delete.asp" يحتوي الملف على التعليمات البرمجية المصدر على كيفية إنشاء حقول الإدخال استنادا إلى الحقول من سجل واحد في جدول قاعدة البيانات. كما أنه يحتوي على "Delete record" الزر الذي سيتم حذف السجل الحالي:

<html>
<body>

<h2>Delete Record</h2>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

cid=Request.Form("customerID")

if Request.form("companyname")="" then
  set rs=Server.CreateObject("ADODB.Recordset")
  rs.open "SELECT * FROM customers WHERE customerID='" & cid & "'",conn
  %>
  <form method="post" action="demo_delete.asp">
  <table>
  <%for each x in rs.Fields%>
  <tr>
  <td><%=x.name%></td>
  <td><input name="<%=x.name%>" value="<%=x.value%>"></td>
  <%next%>
  </tr>
  </table>
  <br><br>
  <input type="submit" value="Delete record">
  </form>
<%
else
  sql="DELETE FROM customers"
  sql=sql & " WHERE customerID='" & cid & "'"
  on error resume next
  conn.Execute sql
  if err<>0 then
    response.write("No update permissions!")
  else
    response.write("Record " & cid & " was deleted!")
  end if
end if
conn.close
%>

</body>
</html>

❮ السابق التالي الفصل ❯